把 Jenkins 流水线从内联脚本重构为从 SCM 读取：Pipeline as Code 实践与踩坑

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17

<definition class="org.jenkinsci.plugins.workflow.cps.CpsScmFlowDefinition" plugin="workflow-cps@...">
  <scm class="hudson.plugins.git.GitSCM" plugin="git@...">
    <userRemoteConfigs>
      <hudson.plugins.git.UserRemoteConfig>
        <url>http://scm.example.com:3000/team/jenkins-pipelines.git</url>
        <credentialsId>gitea-deploy</credentialsId>
      </hudson.plugins.git.UserRemoteConfig>
    </userRemoteConfigs>
    <branches>
      <hudson.plugins.git.BranchSpec>
        <name>*/main</name>
      </hudson.plugins.git.BranchSpec>
    </branches>
  </scm>
  <scriptPath>FM270_RK_Build_Pipeline/Jenkinsfile</scriptPath>
  <lightweight>true</lightweight>
</definition>

1
2
3
4
5
6
7

triggers {
    cron('TZ=Asia/Shanghai\nH 2 * * 1-5')   // 上海时区，工作日 2 点附近
}
parameters {
    booleanParam(name: 'PUBLISH_TO_ZENTAO', defaultValue: true,
                 description: '编译并上传成功后，在项目管理平台创建构建记录')
}

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155

// FM270_RK_Build Pipeline（脱敏示例）
// 部署：Pipeline script from SCM → Script Path = FM270_RK_Build_Pipeline/Jenkinsfile

pipeline {
    agent { label 'build-node-01' }

    parameters {
        booleanParam(
            name: 'PUBLISH_TO_ZENTAO',
            defaultValue: true,
            description: '编译并上传成功后，在项目管理平台(禅道)创建构建记录'
        )
    }

    options {
        timeout(time: 8, unit: 'HOURS')
        disableConcurrentBuilds()
        buildDiscarder(logRotator(numToKeepStr: '20'))
    }

    triggers {
        // 工作日 2 点附近（上海时区）
        cron('TZ=Asia/Shanghai\nH 2 * * 1-5')
    }

    environment {
        PIPELINE_DIR = "${WORKSPACE}/FM270_RK_Build_Pipeline"
        SDK_DIR = '/srv/sdk/fm270-rv1103b'
        ZPRJ    = 'zprj/fm270/yqjy/jm2x0_cd1xxx_4k_apps/'

        SCP_USER = 'artifact'
        SCP_HOST = '10.0.0.30'
        SCP_ROOT = '/srv/artifacts/fm270-build'
        SCP_KEY  = '/home/builduser/.ssh/id_rsa_artifact'

        FTP_DIR  = 'fm270-build'
    }

    stages {

        stage('1. 生成链接文件') {
            steps {
                dir("${SDK_DIR}") {
                    sh 'cd zcommon && ./create_ln.sh && cd ..'
                }
            }
        }

        stage('2. 切换分支') {
            steps {
                dir("${SDK_DIR}") {
                    sh './zswitch_branch.sh xm_uni_branch_linux'
                }
            }
        }

        stage('3. 更新代码') {
            steps {
                dir("${SDK_DIR}") {
                    sh './pull_code.sh'
                }
            }
        }

        stage('4. 再次生成链接文件') {
            steps {
                dir("${SDK_DIR}") {
                    sh 'cd zcommon && ./create_ln.sh && cd ..'
                }
            }
        }

        stage('5. Docker 编译') {
            steps {
                dir("${SDK_DIR}") {
                    // 进入编译容器，去掉 -t（无 TTY），直接执行编译命令
                    sh '''
                        docker run --rm -i --entrypoint /bin/bash \
                            --mount type=bind,source=$(pwd)/,target=/home/SDK_DIR \
                            --net host \
                            --user $(id -u):$(id -g) \
                            --workdir /home/SDK_DIR \
                            rk-build-image:v1.1 \
                            -c "source zmake zprj/fm270/yqjy/jm2x0_cd1xxx_4k_apps/"
                    '''
                }
            }
        }

        stage('6. 上传到产物服务器') {
            steps {
                dir("${SDK_DIR}") {
                    script {
                        def latest = sh(script: 'ls -t output | head -1', returnStdout: true).trim()
                        if (!latest) {
                            error '未在 output/ 下找到时间目录，编译产物可能缺失'
                        }
                        env.OUT_DIR = latest
                        env.verName = latest.replace('.zip', '')   // 去掉版本目录名里的 .zip
                        env.BUILD_NAME = env.verName
                    }
                    sh '''
                        R620_KEY="${SCP_KEY}"
                        chmod 600 "$R620_KEY"
                        verPath="${SCP_ROOT}/${verName}"
                        ssh -o StrictHostKeyChecking=no -i "$R620_KEY" ${SCP_USER}@${SCP_HOST} "mkdir -p ${verPath}"
                        if [ -d "output/${OUT_DIR}" ]; then
                            scp -o StrictHostKeyChecking=no -i "$R620_KEY" -r "output/${OUT_DIR}/." ${SCP_USER}@${SCP_HOST}:"${verPath}/"
                        else
                            scp -o StrictHostKeyChecking=no -i "$R620_KEY" -r "output/${OUT_DIR}" ${SCP_USER}@${SCP_HOST}:"${verPath}/"
                        fi
                        echo "${verName}" | ssh -o StrictHostKeyChecking=no -i "$R620_KEY" ${SCP_USER}@${SCP_HOST} "cat > ${SCP_ROOT}/latest.txt"
                    '''
                    echo "OK 已上传: fm270-build/${verName}/"
                }
            }
        }

        stage('7. 发布到项目管理平台') {
            when {
                expression { return params.PUBLISH_TO_ZENTAO }
            }
            steps {
                script {
                    if (!env.BUILD_NAME?.trim()) {
                        error 'BUILD_NAME 为空，无法发布（请确认上传阶段已产生 verName）'
                    }
                    sh """
                        export BUILD_NAME='${env.BUILD_NAME}'
                        export FTP_DIR='${env.FTP_DIR}'
                        export CHANGES_SINCE_LAST='自动构建发布（FM270_RK_Build Pipeline）'
                        bash '${PIPELINE_DIR}/scripts/publish_to_zentao.sh'
                    """
                }
            }
        }
    }

    post {
        always {
            emailext (
                subject: "FM270 每日构建 ${currentBuild.currentResult}：${env.JOB_NAME} #${env.BUILD_NUMBER}",
                body: """构建结果：${currentBuild.currentResult}
构建任务：${env.JOB_NAME} #${env.BUILD_NUMBER}
构建链接：${env.BUILD_URL}
编译产物已上传至产物服务器: fm270-build/${verName}/。
项目管理平台发布：${params.PUBLISH_TO_ZENTAO ? '已开启' : '未开启'}
详细日志请查看构建 Console Output。""",
                to: 'dev1@corp.example.com, dev2@corp.example.com, dev3@corp.example.com, dev4@corp.example.com, dev5@corp.example.com, dev6@corp.example.com'
            )
        }
        success { echo '构建并上传成功' }
        failure { echo '构建或上传失败，请查看上方各 Stage 日志' }
    }
}